Dosiero:Standard symmetric pdfs.svg

Paĝenhavo ne ekzistas en aliaj lingvoj.
El Vikipedio, la libera enciklopedio

Bildo en pli alta difino ‎(SVG-dosiero, 400 × 300 rastrumeroj, grandeco de dosiero: 390 KB)

Jen dosiero de la Wikimedia-Komunejo. La priskribo en ties priskriba paĝo estas montrata suben.
La Komunejo estas dosieruja retejo de libere licencitaj dosieroj.

Resumo

Priskribo
English: Plot of several symmetric unimodal probability densities with unit variance. From highest to lowest peak:
 
red, kurtosis 3, Laplace (D)ouble exponential distribution;
 
orange, kurtosis 2, hyperbolic (S)ecant distribution;
 
green, kurtosis 1.2, (L)ogistic distribution;
 
black, kurtosis 0, (N)ormal distribution;
 
cyan, kurtosis −0.593762…, raised (C)osine distribution;
 
blue, kurtosis −1, (W)igner semicircle distribution;
 
magenta, kurtosis −1.2, (U)niform distribution.
Dato
Fonto MarkSweep
Aŭtoro  
Vektoro:
Permeso
(Reuzo de la dosiero)
Public domain This chart is ineligible for copyright and therefore in the public domain, because it consists entirely of information that is common property and contains no original authorship. For more information, see Commons:Threshold of originality § Charts

العربية | Deutsch | English | español | français | italiano | 日本語 | македонски | română | русский | slovenščina | 中文（简体） | 中文（繁體） | +/−

Mi, la posedanto de la aŭtorrajto por ĉi tiu verko, ĉi-maniere publikigas tiun laŭ la jena permesilo:
Creative Commons CC-Zero Ĉi tiu dosiero estas disponebla laŭ la Krea Komunaĵo CC0 1.0 Universala Publikaĵiga Dediĉo.
La persono kiu asociis verkon kun ĉi tiu faro dediĉis la verkon kiel publikaĵon forlasante ĉiujn siajn rajtojn al la verko mondvaste sub aŭtorrajta leĝo inkluzivante ĉiujn rilatajn aŭ najbarajn rajtojn permesitajn de leĝo. Oni povas kopii, modifi, distribui kaj ludi la verkon, eĉ por komercaj kialoj, ĉiuj sen peto de permeso.

Ceteraj versioj File:Standard symmetric pdfs logscale.svg
File:Standard symmetric pdfs.png
File:Standard symmetric pdfs logscale.png
SVG genesis
InfoField
 
The SVG code is valid.
 
Ĉi tiu dosiero estas kreita per Gnuplot.
Fontkodo
InfoField

Gnuplot code

# Laplace double exponential distribution, kurtosis 3
laplace(x) = exp(-abs(x)*sqrt(2)) * sqrt(0.5)

# sech distribution, kurtosis 2
sech(x) = 2.0 / (exp(x) + exp(-x))
sech_pdf(x) = 0.5 * sech(0.5*pi*x)

# logistic distribution, kurtosis 1.2
slogist = sqrt(3) / pi
logist(x) = exp(-x/slogist) / slogist / (1 + exp(-x/slogist))**2

# normal distribution, kurtosis 0
n(x) = exp(-0.5*x*x) / sqrt(2*pi)

# raised cosine distribution, kurtosis -0.59376
scos = 1.0 / sqrt(1/3.0 - 2/pi**2)
cosine(x) = abs(x)>scos? 0 : (1+cos(x*pi/scos))*0.5/scos

# Wigner semicircle distribution, kurtosis -1
wigner(x) = abs(x)>2? 0 : sqrt(4-x*x)*0.5/pi

# uniform distribution, kurtosis -1.2
uniform(x) = abs(x)>sqrt(3)? 0 : 0.5/sqrt(3)

set samples 6001
set grid

set xrange [-5.4:5.4]
set xtics 1

set key right font ",8" enhanced

set terminal svg size 400,300 enhanced fname 'DejaVu Sans'  fsize 10 butt solid
set output 'Standard symmetric pdfs.svg'

plot \
     laplace(x)  lt 1 lw 2 title "D,  3", \
     sech_pdf(x) lt 8 lw 2 title "S,  2", \
     logist(x)   lt 2 lw 2 title "L,  1.2", \
     n(x)        lt 7 lw 2 title "N,  0", \
     cosine(x)   lt 5 lw 2 title "C, -0.59376", \
     wigner(x)   lt 3 lw 2 title "W, -1", \
     uniform(x)  lt 4 lw 2 title "U, -1.2"

Titoloj

Donu unulinian priskribon de la enhavo de ĉi tiu dosiero

Eroj prezentitaj en ĉi tiu dosiero

montras

Dosierhistorio

Alklaku iun daton kaj horon por vidi kiel la dosiero tiam aspektis.

Dato/HoroBildetoGrandecojUzantoKomento
nun16:15, 26 maj. 2020Bildeto por versio ekde 16:15, 26 maj. 2020400 × 300 (390 KB)Andelsmall legend tweak
13:52, 26 maj. 2020Bildeto por versio ekde 13:52, 26 maj. 2020400 × 300 (390 KB)Andel== {{int:filedesc}} == {{Information |description=|Description= {{en|1=Plot of several symmetric unimodal probability densities with unit variance. From highest to lowest peak: {{Legend|red|red, kurtosis 3, Laplace (D)ouble exponential distribution;}} {{Legend|orange|orange, kurtosis 2, hyperbolic (S)ecant distribution;}} {{Legend|green|green, kurtosis 1.2, (L)ogistic distribution;}} {{Legend|black|bla...

La jena paĝo ligas al ĉi tiu dosiero:

Suma uzado de la dosiero

La jenaj aliaj vikioj utiligas ĉi tiun dosieron:

Metadatumoj

Ĉi tiu dosiero entenas aldonan informon, probable aldonitan de la diĝita fotilo aŭ skanilo uzita por ĝin krei aŭ diĝitigi. Se la dosiero estas modifita disde sia originala stato, detaloj povas ne ĝuste priskribi tiun modifitan bildon.

Elŝutita el "https://eo.wikipedia.org/wiki/Dosiero:Standard_symmetric_pdfs.svg"